rpgregions-2/build.gradle

plugins {
    id 'com.github.johnrengelman.shadow' version '7.0.0'
    id 'java'
}

group = pluginGroup
version = pluginVersion

java.sourceCompatibility = JavaVersion.VERSION_16
java.targetCompatibility = JavaVersion.VERSION_16

repositories {
    mavenCentral()
    mavenLocal()

    maven { url 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }

    maven { url 'https://repo.codemc.io/repository/maven-snapshots/' }

    maven { url 'https://jitpack.io' }

    maven {
        name 'papermc-repo'
        url 'https://papermc.io/repo/repository/maven-public/'
    }

    maven {
        name 'sonatype'
        url 'https://oss.sonatype.org/content/groups/public/'
    }

    maven { url "https://repo.aikar.co/content/groups/aikar/" }

    // worldguard
    maven { url "https://maven.enginehub.org/repo/" }

    // PAPI
    maven { url 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }

    // MythicMobs
    maven { url 'https://mvn.lumine.io/repository/maven-public/' }

    // Dynmap
    maven { url 'https://repo.mikeprimm.com' }

    flatDir { dir '../libraries' }
}

dependencies {
    testImplementation group: 'junit', name: 'junit', version: '4.5'
    implementation project(':rpgregions')
    implementation project(':modern')
    implementation project(':api')
}

tasks.shadowJar {
    dependencies {
        exclude(dependency {
            it.moduleGroup == 'commons-io'
        })
        exclude(dependency {
            it.moduleGroup == 'commons-codec'
        })
    }
    relocate 'net.islandearth.languagy', 'net.islandearth.rpgregions.libs.languagy'
    relocate 'co.aikar.commands', 'net.islandearth.rpgregions.libs.acf'
    relocate 'co.aikar.idb', 'net.islandearth.rpgregions.libs.idb'
    relocate 'com.github.stefvanschie.inventoryframework', 'net.islandearth.rpgregions.libs.inventoryframework'
    relocate 'org.bstats', 'net.islandearth.rpgregions.libs.bstats'
    relocate 'io.papermc.lib', 'net.islandearth.rpgregions.libs.paperlib'
    relocate 'net.wesjd', 'net.islandearth.rpgregions.libs.anvilgui'
}

tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"

    // Force warnings
    options.compilerArgs << '-Xlint:all'
    options.deprecation = true
}

build.dependsOn shadowJar

import org.apache.tools.ant.filters.ReplaceTokens

processResources {
    filter ReplaceTokens, tokens: [version: version]
}