mirror of
https://github.com/LeavesMC/Leaves.git
synced 2025-12-19 14:59:32 +00:00
93 lines
2.8 KiB
Plaintext
93 lines
2.8 KiB
Plaintext
import io.papermc.paperweight.util.*
|
|
import kotlin.io.path.*
|
|
|
|
plugins {
|
|
java
|
|
`maven-publish`
|
|
id("com.github.johnrengelman.shadow") version "8.1.1" apply false
|
|
id("io.papermc.paperweight.patcher") version "1.5.11"
|
|
}
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
maven("https://repo.leavesmc.top/releases") {
|
|
content { onlyForConfigurations("paperclip") }
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
remapper("net.fabricmc:tiny-remapper:0.10.1:fat")
|
|
decompiler("net.minecraftforge:forgeflower:2.0.627.2")
|
|
paperclip("top.leavesmc:leavesclip:1.0.2")
|
|
}
|
|
|
|
subprojects {
|
|
apply(plugin = "java")
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion.set(JavaLanguageVersion.of(17))
|
|
}
|
|
}
|
|
|
|
tasks.withType<JavaCompile> {
|
|
options.encoding = Charsets.UTF_8.name()
|
|
options.release.set(17)
|
|
}
|
|
tasks.withType<Javadoc> {
|
|
options.encoding = Charsets.UTF_8.name()
|
|
}
|
|
tasks.withType<ProcessResources> {
|
|
filteringCharset = Charsets.UTF_8.name()
|
|
}
|
|
|
|
repositories {
|
|
mavenLocal()
|
|
mavenCentral()
|
|
maven("https://oss.sonatype.org/content/groups/public/")
|
|
maven("https://papermc.io/repo/repository/maven-public/")
|
|
maven("https://ci.emc.gs/nexus/content/groups/aikar/")
|
|
maven("https://repo.aikar.co/content/groups/aikar")
|
|
maven("https://repo.md-5.net/content/repositories/releases/")
|
|
maven("https://hub.spigotmc.org/nexus/content/groups/public/")
|
|
maven("https://jitpack.io")
|
|
}
|
|
}
|
|
|
|
paperweight {
|
|
serverProject.set(project(":leaves-server"))
|
|
|
|
remapRepo.set("https://maven.fabricmc.net/")
|
|
decompileRepo.set("https://files.minecraftforge.net/maven/")
|
|
|
|
usePaperUpstream(providers.gradleProperty("paperRef")) {
|
|
withPaperPatcher {
|
|
apiPatchDir.set(layout.projectDirectory.dir("patches/api"))
|
|
apiOutputDir.set(layout.projectDirectory.dir("leaves-api"))
|
|
|
|
serverPatchDir.set(layout.projectDirectory.dir("patches/server"))
|
|
serverOutputDir.set(layout.projectDirectory.dir("leaves-server"))
|
|
}
|
|
|
|
patchTasks.register("generatedApi") {
|
|
isBareDirectory = true
|
|
upstreamDirPath = "paper-api-generator/generated"
|
|
patchDir = layout.projectDirectory.dir("patches/generated-api")
|
|
outputDir = layout.projectDirectory.dir("paper-api-generator/generated")
|
|
}
|
|
}
|
|
}
|
|
|
|
if (providers.gradleProperty("updatingMinecraft").getOrElse("false").toBoolean()) {
|
|
|
|
tasks.withType<io.papermc.paperweight.tasks.CollectATsFromPatches>().configureEach {
|
|
val dir = layout.projectDirectory.dir("patches/unapplied")
|
|
if (dir.path.isDirectory()) {
|
|
extraPatchDir = dir
|
|
}
|
|
}
|
|
tasks.withType<io.papermc.paperweight.tasks.RebuildGitPatches>().configureEach {
|
|
filterPatches = false
|
|
}
|
|
}
|