mirror of
https://github.com/GeyserMC/Geyser.git
synced 2025-12-19 14:59:27 +00:00
e2f873466b
* Update gradle to 9.2.0 * Eclipse doesn't like defining a generic in an instanceof check... Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Fix launching on standalone due to Gradle 9 changes Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Update indra to v4; fix as many gradle deprecation warnings as possible Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Do task order suggestion; remove properties comment line Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Fix fabric runServer rask Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Fix :neoforge:runServer gradle task Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> * Fix libs.versions.toml * Fix dupe runtask def * Update architectury-loom and resolve properties issues --------- Signed-off-by: Joshua Castle <26531652+Kas-tle@users.noreply.github.com> Co-authored-by: onebeastchris <github@onechris.mozmail.com>
93 lines
2.8 KiB
Plaintext
93 lines
2.8 KiB
Plaintext
plugins {
|
|
id("geyser.platform-conventions")
|
|
id("geyser.modrinth-uploading-conventions")
|
|
alias(libs.plugins.runpaper)
|
|
}
|
|
|
|
dependencies {
|
|
api(projects.core)
|
|
api(libs.erosion.bukkit.common) {
|
|
isTransitive = false
|
|
}
|
|
|
|
implementation(libs.erosion.bukkit.nms) {
|
|
attributes {
|
|
attribute(TargetJvmVersion.TARGET_JVM_VERSION_ATTRIBUTE, 21)
|
|
}
|
|
}
|
|
|
|
implementation(variantOf(libs.adapters.spigot) {
|
|
classifier("all") // otherwise the unshaded jar is used without the shaded NMS implementations
|
|
})
|
|
implementation(variantOf(libs.adapters.paper) {
|
|
classifier("all") // otherwise the unshaded jar is used without the shaded NMS implementations
|
|
})
|
|
|
|
implementation(libs.cloud.paper)
|
|
implementation(libs.commodore)
|
|
|
|
implementation(libs.adventure.text.serializer.bungeecord)
|
|
|
|
compileOnly(libs.folia.api)
|
|
|
|
compileOnlyApi(libs.viaversion)
|
|
|
|
// For 1.16.5/1.17.1
|
|
implementation(libs.gson.record.factory) {
|
|
isTransitive = false
|
|
}
|
|
}
|
|
|
|
platformRelocate("it.unimi.dsi.fastutil")
|
|
// Relocate net.kyori but exclude the component logger
|
|
platformRelocate("net.kyori", "net.kyori.adventure.text.logger.slf4j.ComponentLogger")
|
|
platformRelocate("org.objectweb.asm")
|
|
platformRelocate("me.lucko.commodore")
|
|
platformRelocate("org.incendo")
|
|
platformRelocate("io.leangen.geantyref") // provided by cloud and Configurate, should also be relocated
|
|
platformRelocate("org.yaml") // Broken as of 1.20
|
|
platformRelocate("org.spongepowered")
|
|
platformRelocate("marcono1234.gson")
|
|
platformRelocate("org.bstats")
|
|
|
|
provided(libs.viaversion)
|
|
|
|
tasks.withType<Jar> {
|
|
manifest.attributes["Main-Class"] = "org.geysermc.geyser.platform.spigot.GeyserSpigotMain"
|
|
}
|
|
|
|
tasks.withType<com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar> {
|
|
|
|
// Prevents Paper 1.20.5+ from remapping Geyser
|
|
manifest {
|
|
attributes["paperweight-mappings-namespace"] = "mojang"
|
|
}
|
|
|
|
archiveBaseName.set("Geyser-Spigot")
|
|
|
|
dependencies {
|
|
exclude(dependency("com.google.*:.*"))
|
|
|
|
// Needed because older Spigot builds do not provide the haproxy module
|
|
exclude("io.netty", libs.netty.codec.haproxy)
|
|
|
|
// Commodore includes Brigadier
|
|
exclude(dependency("com.mojang:.*"))
|
|
}
|
|
}
|
|
|
|
modrinth {
|
|
uploadFile.set(tasks.getByPath("shadowJar"))
|
|
gameVersions.addAll("1.16.5", "1.17", "1.17.1", "1.18", "1.18.1", "1.18.2", "1.19",
|
|
"1.19.1", "1.19.2", "1.19.3", "1.19.4", "1.20", "1.20.1", "1.20.2", "1.20.3", "1.20.4", "1.20.5", "1.20.6",
|
|
"1.21", "1.21.1", "1.21.2", "1.21.3", "1.21.4", "1.21.5", "1.21.6", "1.21.7", "1.21.8")
|
|
loaders.addAll("spigot", "paper")
|
|
}
|
|
|
|
tasks {
|
|
runServer {
|
|
minecraftVersion(libs.versions.runpaperversion.get())
|
|
jvmArgs("-Dcom.mojang.eula.agree=true")
|
|
}
|
|
}
|