Initial move to gradle

2025-12-19 14:59:27 +00:00 · 2022-02-27 16:38:55 -06:00
parent 354e87b747
commit 6321ecc166
50 changed files with 1052 additions and 1279 deletions
--- a/build-logic/src/main/kotlin/geyser.shadow-conventions.gradle.kts
+++ b/build-logic/src/main/kotlin/geyser.shadow-conventions.gradle.kts
@@ -0,0 +1,55 @@
+import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
+
+plugins {
+    id("geyser.base-conventions")
+    id("com.github.johnrengelman.shadow")
+    id("com.jfrog.artifactory")
+}
+
+tasks {
+    named<Jar>("jar") {
+        archiveClassifier.set("unshaded")
+        from(project.rootProject.file("LICENSE"))
+    }
+    val shadowJar = named<ShadowJar>("shadowJar") {
+        archiveBaseName.set(project.name)
+        archiveVersion.set("")
+        archiveClassifier.set("")
+
+        val sJar: ShadowJar = this
+
+        doFirst {
+            providedDependencies[project.name]?.forEach { string ->
+                sJar.dependencies {
+                    println("Excluding $string from ${project.name}")
+                    exclude(dependency(string))
+                }
+            }
+        }
+    }
+    named("build") {
+        dependsOn(shadowJar)
+    }
+}
+
+publishing {
+    publications.named<MavenPublication>("mavenJava") {
+        artifact(tasks["shadowJar"])
+        artifact(tasks["sourcesJar"])
+    }
+}
+
+artifactory {
+    publish {
+        repository {
+            setRepoKey("maven-snapshots")
+            setMavenCompatible(true)
+        }
+        defaults {
+            publishConfigs("archives")
+            setPublishArtifacts(true)
+            setPublishPom(true)
+            setPublishIvy(false)
+        }
+    }
+}